Конференция Opera AC community

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$sOperaDir = @ScriptDir & '\..'
$sUrlFilterFile = $sOperaDir & '\profile\urlfilter.ini'
$sCurrent_URL = 'http://www.googleadservices.com/pagead/aclk?sa=L&ai=CWKtFGK8CTK3QKcT--QafuvRzhuq-' ;$CmdLine[1]

_URLFilter_GetBlockingFilters($sUrlFilterFile, $sCurrent_URL)

Func _URLFilter_GetBlockingFilters($sUrlFilterFile, $sURL, $hParent_GUI = 0)
    Local $sFilters, $aFilters, $sBlock_Filters, $hBlockFilter_GUI, $nBlockFilter_Edit, $nBlockFilter_OkButton

    $sFilters = FileRead($sUrlFilterFile)
    $sFilters = StringRegExpReplace($sFilters, "(?si).*\[exclude\][\r\n]*", "")
    $sFilters = StringStripCR($sFilters)
    $sFilters = StringStripWS($sFilters, 3)
    $sFilters = StringReplace($sFilters, "\", "\\")
    $sFilters = StringReplace($sFilters, ".", "\.")
    $sFilters = StringReplace($sFilters, "*", ".*")

    $aFilters = StringSplit($sFilters, @LF)
    $sBlock_Filters = ""

    For $i = 1 To $aFilters[0]
        If StringRegExp($sURL, "(?i)" & $aFilters[$i]) Then
            $sFilters = StringReplace($aFilters[$i], "\\", "\")
            $sFilters = StringReplace($sFilters, "\.", ".")
            $sFilters = StringReplace($sFilters, ".*", "*")

            $sBlock_Filters &= $sFilters & @CRLF
        EndIf
    Next

    GUISetState(@SW_DISABLE, $hParent_GUI)

    $hBlockFilter_GUI = GUICreate("Blocking URL Filters", 300, 400, -1, -1, BitOR($WS_CAPTION, $WS_POPUP, $WS_SYSMENU), -1, $hParent_GUI)
    GUICtrlCreateLabel("The following filters are blocking the current url:", 20, 10, 270, 20)
    GUICtrlSetFont(-1, 8.5, 800)
    GUICtrlCreateInput($sURL, 20, 25, 260, 20)
    $nBlockFilter_Edit = GUICtrlCreateEdit(StringStripWS($sBlock_Filters, 2), 20, 60, 260, 300)
    $nBlockFilter_OkButton = GUICtrlCreateButton("OK", 120, 370, 60, 20)
    GUICtrlSetState($nBlockFilter_OkButton, $GUI_FOCUS)

    GUISetState(@SW_SHOW, $hBlockFilter_GUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $nBlockFilter_OkButton
                ExitLoop
        EndSwitch
    WEnd

    GUISetState(@SW_ENABLE, $hParent_GUI)
    GUIDelete($hBlockFilter_GUI)

    Return $sBlock_Filters
EndFunc